The radial nul geodesics are solutions to 
(dt/dr)=±(((1-(2/r)))^(-1))
which gives the direction of light cones.

{∫ (1/(1-(2/r)))\[DifferentialD]r,(1/(2M))∫ (1/(1-((2M)/r)))\[DifferentialD]r}

t   [r_,t0_]:= r + 2 Log[  (r/2)-1]+t0 ;
ti[r_,t0_]:= r + 2 Log[-(r/2)+1]+t0 ;
dt[r_]:= (1/(1-(2/r))); (* gives slope *)

Create a Light Cone graphics object:

lightCone[x0_,y0_,len_,slope_,color_]:= Module[
{x1,y1,x2,y2,x3,y3,x4,y4,θ,cone,l},
l=Abs[len];
If[slope>0,
θ=ArcTan[slope],
θ=ArcTan[slope]+π
];(* ArcTan gives ((-π)/2) <= θ <= (π/2)*)
x1=x0+l Cos[θ];y1= y0+ l Sin[θ];
x2=x0-l Cos[θ];y2= y0+ l Sin[θ];
x3=x0-l Cos[θ];y3= y0- l Sin[θ];
x4=x0+l Cos[θ];y4= y0- l Sin[θ];
If[slope>0,
cone=Polygon[{{x1,y1},{x2,y2},{x0,y0},{x4,y4},{x3,y3},{x0,y0}}],
cone=Polygon[{{x1,y1},{x4,y4},{x0,y0},{x2,y2},{x3,y3},{x0,y0}}]
];
Graphics[{color,cone}]
];
Show[{lightCone[0,0,1,1,Red],lightCone[2,3,1,-1,Blue]}];

rmin=   0.0;rmax=5.0;rS=2.0;
tmin=-4.5;tmax=4.5;
g0=Graphics[{Opacity[0.15],Red,Rectangle[{0,tmin},{rS,tmax+1}]}];
g1=Plot[
Table[   t[r,t0],{t0,{0.0,   3,-3,-6}}],{r,2.05,rmax}(*,PlotStyle->{Magenta}*)
];
g2=Plot[
Table[-t[r,t0],{t0,{0.0,-4,-7         }}],{r,2.05,rmax}(*,PlotStyle->{Magenta}*)
];
(*Create light cones: *)
t01=    3.0;t02=  0.0; rp=r/.FindRoot[t[r,t01]==-t[r,t02],{r,4.2}];tp=t[rp,t01];
g4=lightCone[rp,tp,0.8,dt[rp],Magenta];
t01=   0.0;t02=-4.0; rp=r/.FindRoot[t[r,t01]==-t[r,t02],{r,4.2}];tp=t[rp,t01];
g5=lightCone[rp,tp,0.8,dt[rp],Magenta];
t01=-3.0;t02=-7.0; rp=r/.FindRoot[t[r,t01]==-t[r,t02],{r,4.2}];tp=t[rp,t01];
g6=lightCone[rp,tp,0.8,dt[rp],Magenta];
(*Inside rS: *)
h1=Plot[
Table[   ti[r,t0],{t0,{-2,0.0,2,4}}],{r,0.05,1.99},PlotStyle->{Black}
];
h2=Plot[
Table[ -ti[r,t0],{t0,{-1.0,1.0,3.0}}],{r,0.05,1.99},PlotStyle->{Black}
];
(*Create light cones: *)
color=RGBColor["#42703d"];
t01=    4.0;t02=  3.0; rp=r/.FindRoot[ti[r,t01]==-ti[r,t02],{r,1.1}];tp=ti[rp,t01];
h3=lightCone[rp,tp,1.10,dt[rp],color];
t01=    0.0;t02=  3.0; rp=r/.FindRoot[ti[r,t01]==-ti[r,t02],{r,1.1}];tp=ti[rp,t01];
h4=lightCone[rp,tp,0.60,dt[rp],color];
t01= -2.0;t02=  3.0; rp=r/.FindRoot[ti[r,t01]==-ti[r,t02],{r,1.1}];tp=ti[rp,t01];
h5=lightCone[rp,tp,0.35,dt[rp],color];
Show[g0,g1,g2,g4,g5,g6,h1,h2,h3,h4,h5,
PlotRange-> {{rmin,rmax},{tmin,tmax}},AspectRatio-> 1,Axes-> True,AxesLabel->{"r","t"}]

Plot[10-r-2Log[Abs[(r/2)-1]],{r,0.1,4}]